%{
/*
 * Copyright (c) 1995, 1996 Gunther Schadow.  All rights reserved.
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 * 
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 * 
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
 */
/*
 * C DECLARATIONS
 */

#include "abl300.h"
#include "results.h"

extern "C" {
void yyerror(const char *);
int yylex();
}

class Header *the_header;
class Battery *the_battery;
%}

%union {
  long   integer;
  char  *string;
  char   chr;
  void  *object;
  int    symbol;
  bool   boolean;
  struct Job       *message;
  struct Header    *header;
  struct Batteries *batteries;
  struct Battery   *battery;
  struct Result    *result;
  struct TimeStamp *timestamp;
  struct Date      *date;
  struct Time      *time;
}

/*
 * TOKENS
 */

%token <symbol> COPY
%token <symbol> PROG
%token <symbol> TIME
%token <symbol> DATE
%token <symbol> OPID
%token <symbol> PTID
%token <symbol> SPEC

/* The following four blocks of terminals are used as coded values. Thus
 * they are presented as tables. Each of them begin with a symbol named
 * like "<table name>_ORG" and "<table>_END" (e.g. MEASUREMENT_ORG and
 * MEASUREMENT_END). It is assumed that the yacc (or bison) program will
 * make integer macros from the %token directives preserving the sequence
 * of occurence in the yacc source. Thus, the ..._ORG and ..._END symbols
 * denotes the origins and ends of the tables and are not used as terminal
 * tokens by themselves nor do they have any other meaning apart from a mere
 * offset.
 *
 * The tables are:
 * 1. SPECIMEN CODE
 * 2. MEASUREMENT CODE
 * 3. UNIT CODE while units are already translated to ISO+ units
 *              by the scanner (returning a string rather than a symbol)
 * 4. ANALYZER CODE
 */


%token SPECIMEN_ORG
/* SPEC CODE
 */
%token <symbol> BLANK_SPEC
%token <symbol> CAPILLARY_SPEC
%token <symbol> ARTERIAL_SPEC
%token <symbol> VENOUS_SPEC
%token <symbol> GAS_SPEC
/* quality check codes */
%token <symbol> QC_UNKNOWN_SPEC
%token <symbol> QC_S2030_SPEC
%token <symbol> QC_S2040_SPEC
%token <symbol> QC_S2050_SPEC
%token <symbol> QC_S2060_SPEC
/* implicit specimen for entered values */
%token <symbol> IHG_SPEC /* inhaled gas: FIO2 */
%token <symbol> PAT_SPEC /* patient: TEMP */
%token <symbol> BLD_SPEC /* where artherial/venous is meaningless (E'lytes) */
%token SPECIMEN_END

%token MEASUREMENTS_ORG
/* MEASUREMENTS
 *
 *              ABL    MEANING				 FORMAT
 *              -----  --------------------------------- -----------------*/
%token <symbol> ABE    /* actual base excess		 value G% MM/L */
%token <symbol> BARO   /* barometric pressure		 value MMHG KPA */
%token <symbol> CA     /* actual calcium value		 value MM/L */
%token <symbol> CA_S   /* corrected calcium value	 value MM/L */
%token <symbol> CO2    /* CO2 content			 value % */
%token <symbol> FCO2   /* CO2 content (fraction)         value */
%token <symbol> FO2    /* O2 content (fraction)		 value */
%token <symbol> H      /* free protons			 value NM/L */
%token <symbol> HB     /* hemoglobin value		 value G% MM/L */
%token <symbol> HBCO   /* HBCO value			 value % */
%token <symbol> HBO2   /* oxygenated hemoglobin value	 value % */
%token <symbol> HCO3   /* bicarbonate value		 value MM/L */
%token <symbol> K      /* potassium value		 value MM/L */
%token <symbol> METHB  /* methemoglobin value		 value % */
%token <symbol> NA     /* sodium value			 value MM/L */
%token <symbol> O2     /* O2 content			 value % */
%token <symbol> O2CT   /* oxigen content value		 value VOL% MM/L */
%token <symbol> P50E   /* P50 value if entered		 value MMHG KPA */
%token <symbol> P50C   /* calculated P50 value		 value MMHG KPA */
%token <symbol> PCO2   /* pCO2 value			 value MMHG KPA */
%token <symbol> PH     /* pH value			 value */
%token <symbol> PO2    /* pO2 value			 value MMGH KPA PA */
%token <symbol> SAT    /* oxigen saturation value	 value % */
%token <symbol> SBC    /* standard bicarbonate value	 value MM/L */
%token <symbol> SBE    /* standard base excess value	 value MM/L */
%token <symbol> TCO2   /* total CO2 value		 value MM/L */

%token <symbol> FIO2   /* fraction of inspired oxygen	 value */
%token <symbol> TEMP   /* patient temperature		 value C F */
%token MEASUREMENTS_END

%token UNITS_ORG
/* UNITS
 *
 *              ABL      ISO(HL7)
 *              -------- --------------*/
%token <symbol> C_UN     /* CEL */
%token <symbol> F_UN     /* DEGF */
%token <symbol> MMHG_UN  /* MM(HG) */
%token <symbol> KPA_UN   /* KPAL */
%token <symbol> PA_UN    /* PAL */
%token <symbol> PC_UN    /* % */
%token <symbol> GPC_UN   /* % */
%token <symbol> VOLPC_UN /* % */
%token <symbol> NMPL_UN  /* NM/L */
%token <symbol> MMPL_UN  /* MMOL/L */
%token <symbol> ONE_UN   /* 1 -- implicit unit */
%token UNITS_END

%token ANALYZERS_ORG
/* ANALYZERS
 */
%token <symbol> PRE_ANA /* pre observations: FIO2 and TEMP */
%token <symbol> DEF_ANA /* default analyzer */
%token <symbol> OSM_ANA /* Hemoximeter */
%token <symbol> ICA_ANA /* Calcium */
%token <symbol> KNA_ANA /* Sodium, Potassium */
%token ANALYZERS_END

/* MONTHNAMES
 */
%token <integer> JAN_MON
%token <integer> FEB_MON
%token <integer> MAR_MON
%token <integer> APR_MON
%token <integer> MAY_MON
%token <integer> JUN_MON
%token <integer> JUL_MON
%token <integer> AUG_MON
%token <integer> SEP_MON
%token <integer> OCT_MON
%token <integer> NOV_MON
%token <integer> DEC_MON

/* VALUES
 */
%token <integer> INT1
%token <integer> INT2
%token <integer> INT3
%token <integer> INT4
%token <integer> INT5_
%token <string>  REAL
%token <chr>     STRINGH
%token <string>  STRING
%token <string>  PTIDVAL

/* MISCELLANEOUS TERMINALS
 */
%token <symbol> EOLN
%token <symbol> SPACE
%token <symbol> QMARK
%token <symbol> COLON
%token <symbol> EMPTYLINE
%token <symbol> SPACES
%token <symbol> DISCARD
%token <symbol> END_OF_FILE

/*
 * NONTERMNINAL SYMBOL TYPES
 */
%type <message> message
%type <message> results_message
%type <symbol>  eom
%type <symbol>  eob
%type <header>  header
%type <header>  head_block
%type <integer> samp_no
%type <integer> intnum
%type <string>  errormsg
%type <string>  errorline
%type <timestamp> time_stamp
%type <time>    time
%type <time>    timeval
%type <date>    date
%type <date>    dateval
%type <integer> month
%type <boolean> qpfx
%type <symbol>  lpfx
%type <integer> opid_block
%type <integer> opid
%type <header>  ptid_block
%type <string>  ptid
%type <battery> pre_values
%type <result>  fio2
%type <result>  temp
%type <symbol>  specimen
%type <symbol>  specval
%type <batteries> body
%type <batteries> results_blocks
%type <battery>   results_block
%type <symbol>  results_block_header
%type <symbol>  analyzer
%type <battery> results
%type <result>  result
%type <symbol>  resultid
%type <symbol>  unit

/*
 * CALIBRATION
 */
%token <symbol> START_UP_CAL
%token <symbol> ONE_POINT_CAL
%token <symbol> TWO_POINT_CAL

%type <symbol> cal_message
%type <symbol> cal_header
%type <symbol> cal_type
%type <symbol> cal_type_val
%type <symbol> cal_body

/*
 * JUNK
 */
%type <symbol> junk_message

%%
/*
 * GRAMMAR RULES
 */

/* message */
message: lpfx results_message { eject($2); YYACCEPT }
 | lpfx cal_message { YYACCEPT }
 | lpfx junk_message { YYACCEPT }
 | lpfx END_OF_FILE { YYACCEPT }
 | END_OF_FILE { YYABORT }
 ;

/* symbol */
eob: EMPTYLINE
  ;

/* symbol */
eom: eob eob
  ;

/* symbol */
lpfx: { $$ = 0 }
  | eob lpfx
  ;

/* message */
results_message : header body {	$$ = new Job($1, $2);
				delete $1; delete $2; }
  ;

/* header */
header: head_block eom { YYACCEPT }
  | head_block opid_block { the_header = $1; } ptid_block { 
    $1->operator_id = $2;
    $$ = $1 }
  ;

/* header */
head_block: samp_no time_stamp errormsg eob { $$ = new Header;
					      $$->sample_no = $1;
					      $$->error = $3;
					      $$->time_stamp = $2; }
  ;

/* integer */
samp_no: qpfx COPY intnum EOLN { $$ = $3 }
  | intnum EOLN { $$ = $1 }
  ;

/* integer */
intnum: INT1 | INT2 | INT3 | INT4 | INT5_
  ;

/* string */
errormsg: { $$ = NULL }
  | errorline errormsg
{ 
  if($2 == NULL)
    $$ = $1;
  else
    {
      size_t l1 = strlen($1), l2 = strlen($2);
      $$ = new char [l1 + 1 + l2 + 1];
      memcpy($$,$1,l1);          delete [] $1;
      $$[l1] = ' ';
      memcpy(&$$[l1 + 1],$2,l2); delete [] $2;
      $$[l1 + 1 + l2] = '\0';
    }
};

/* string */
errorline: qpfx STRINGH { CS(STRING) } STRING { CS(0) } EOLN { $$ = $4;
							       $$[0] = $2; }
     | STRINGH { CS(STRING) } STRING { CS(0) } EOLN { $$ = $3;
						      $$[0] = $1; }
     ;

/* timestamp */
time_stamp: time date { $$ = new TimeStamp($2, $1);
			delete $1;
			delete $2; }
  ;

/* time */
time: qpfx TIME timeval EOLN { $$ = $3; }
  ;

/* time */
timeval: INT2 COLON INT2 { $$ = new Time($1, $3); }
  ;

/* date */
date: qpfx DATE dateval EOLN { $$ = $3; }
  ;

/* date */
dateval: month INT2 INT4 { $$ = new Date($3, $1, $2); }
  ;

/* integer */
month: JAN_MON | FEB_MON | MAR_MON | APR_MON | MAY_MON | JUN_MON
  | JUL_MON | AUG_MON | SEP_MON | OCT_MON | NOV_MON | DEC_MON
  ;

/* boolean */
qpfx: SPACE SPACE { $$ = false }
  | QMARK SPACE { $$ = true }
  ;

/* integer */
opid_block: opid eob { $$ = $1 }
  ;

/* integer */
opid: qpfx OPID INT4 EOLN { $$ = $3 }
  | qpfx OPID EOLN { $$ = -1 }
  ;

/* header ( in the_header ) */
ptid_block: ptid pre_values specimen eob
{
  the_header->patient_id = $1;
  the_header->pre_observ = $2;
  the_header->specimen_type = $3; 
  $$ = the_header;
};

/* string */
ptid: qpfx PTID { CS(PTIDVAL) } PTIDVAL { CS(0) } EOLN { $$ = $4; }
  ;

/* battery */
pre_values: fio2 temp { $$ = new Battery(PRE_ANA);
			$$->append($1);
		        $$->append($2); }
  ;

/* entered result: fio2 may be empty! */
fio2: qpfx FIO2 REAL EOLN { $$ = new Result(IHG_SPEC, $2, $3, ONE_UN); }
  | qpfx FIO2 REAL unit EOLN { $$ = new Result(IHG_SPEC, $2, $3, $4); }
  | qpfx FIO2 EOLN { $$ = new Result(IHG_SPEC, $2, NULL, ONE_UN); }
  | qpfx FIO2 unit EOLN { $$ = new Result(IHG_SPEC, $2, NULL, $4); }
  ;

/* result (might be empty?) */
temp: qpfx TEMP REAL unit EOLN { $$ = new Result(PAT_SPEC, $2, $3, $4); }
  | qpfx TEMP unit EOLN { $$ = new Result(PAT_SPEC, $2, NULL, $4); }
  ;

/* symbol */
specimen: qpfx SPEC specval EOLN { $$ = $3; }

/* symbol */
specval: { $$ = BLANK_SPEC }
  | CAPILLARY_SPEC
  | ARTERIAL_SPEC
  | VENOUS_SPEC
  | GAS_SPEC
  | QC_UNKNOWN_SPEC { exit(0) }
  | QC_S2030_SPEC   { exit(0) }
  | QC_S2040_SPEC   { exit(0) }
  | QC_S2050_SPEC   { exit(0) }
  | QC_S2060_SPEC   { exit(0) }
  ;

/* batteries */
body: results_blocks
  ;

/* batteries */
results_blocks: results_block eom { $$ = new Batteries;
				    $$->append($1); }
  | results_block results_blocks  { $$ = $2;
				    $$->append($1); }
  ;

/* battery */
results_block: results_block_header results { $2->settype($1);
					      $$ = $2; }
  | results { $1->settype(DEF_ANA);
	      $$ = $1; }
  ;

/* symbol */
results_block_header: qpfx analyzer EOLN { $$ = $2 }
  ;

/* symbol */
analyzer: OSM_ANA | ICA_ANA | KNA_ANA 
  ;

/* battery */
results: result errormsg eob { $$ = new Battery;
			       $$->seterror($2);
			       $$->append($1);
			       delete $1; }
  | result results { $2->append($1);
		     delete $1;
		     $$ = $2; }
  ;

/* result */
result: qpfx resultid REAL EOLN   { $$ = new Result(the_header->specimen_type,
						    $2, $3, ONE_UN, $1); }
   | qpfx resultid REAL unit EOLN { $$ = new Result(the_header->specimen_type,
						    $2, $3, $4, $1); }
   | qpfx resultid EOLN           { $$ = new Result(the_header->specimen_type,
						    $2, NULL, ONE_UN, $1); }
   | qpfx resultid unit EOLN      { $$ = new Result(the_header->specimen_type,
						    $2, NULL, $4, $1); }
  ;

/* symbol */
resultid:
    ABE  | BARO | CA   | CA_S  | CO2   | FCO2 | FO2  | H    | HB   | HBCO
  | HBO2 | HCO3 | K    | METHB | NA    | O2   | O2CT | P50E | PCO2 | PH
  | PO2  | SAT  | SBC  | SBE   | TCO2  | P50C
  ;

/* symbol */
unit:
    C_UN     | F_UN    | MMHG_UN | KPA_UN | PA_UN | PC_UN | GPC_UN
  | VOLPC_UN | NMPL_UN | MMPL_UN
  ;

/*
 * Calibration (just forget it)
 */
/* symbol */
cal_message: cal_header cal_body
  ;

/* symbol */
cal_header: samp_no cal_type { $$ = $2 }
  ;

/* symbol */
cal_type: qpfx cal_type_val EOLN { $$ = $2 }
  ;

/* symbol */
cal_type_val: START_UP_CAL | ONE_POINT_CAL | TWO_POINT_CAL
  ;

/* symbol */
cal_body: { CS(DISCARD) } DISCARD { CS(0) } eom
  ;

/*
 * Junk message (just forget ist)
 */
/* symbol */
junk_message: errorline { CS(DISCARD) } DISCARD { CS(0) } eom { $$ = 0 }
  ;


%%
/*
 * ADDITIONAL C CODE
 */